大家好，這裡是回到去年發現的大陸上的小編過路君子

但是身邊跟著的夥伴換人了呢，不再是上次的 LinkIt 7697 了

小編久違的又回去碰物聯網了呢，上次碰是去年四月的時候，那時候使用的是台灣開發的 Linklt 7697。

時過境遷，這次要使用的是中國開發的 NodeMCU ESP8266 這塊板子，話雖如此，但是在使用方式上大同小異，因為都是在 Arduino 上面開發。

不得不說 Arduino 真的強大，可以整合這麼多開發版，不用每換一塊就重新安裝一個環境或重新安裝軟體。

那我們今天的主題便是結合上次我們提到的 ThingSpeak 這個網站來做應用，還沒看過的人可以這邊請：【ThinkSpeak】一個IoT數據分析(IoT analytics)及呈現的網站。

那同時我們會搭配溫度計使用，這次要使用的溫度計是 DHT11；順帶一提，之前小編在使用 Linklt 7697 的時候所使用的溫度計是 DHT22。

那接下來跟上次的文章一樣，廢話不多說，直接來上規格表：

註：USB-SERIAL CP2102 的 載點。

Step1. 安裝 DHT sensor library

(所有圖片點擊都可以放大、變高清)

Step2. 安裝 Thingspeak

這邊 Thingspeak 指的不是那個網站，而是套件名稱，應該算好找，因為全部就只有一個套件叫做 Thingspeak。

Step3. 將溫度計接上板子

這塊 NodeMCU 也是可以外加 Grove 擴充版的，所以小編也插了一塊上去，各位如果沒有擴充版......那就直接把杜邦線插在接腳上吧。

接線方式因為只有三根所以接起來還算簡單，正極接到 3v3 上(紫色線)、負極接地(綠色線)和中間的 OUT 接到 D5 上(藍色線)，當然藍線要接到其他接腳也是可以的，就是等等下方的程式碼要改而已。

因為小編是 DHT11 的溫度計才要搞得那麼複雜，如果各位手上拿的是 DHT22 的溫度計，就直接插上去就可以了，因為它本身就是一個 Grove 接頭。

Step4. 程式碼撰寫

Secrets.h

// Use this file to store all of the private credentials 
// and connection details

#define SECRET_SSID "wifi-name"    // replace MySSID with your WiFi network name
#define SECRET_PASS "wifi-password"  // replace MyPassword with your WiFi password

#define SECRET_CH_ID 0000000      // replace 0000000 with your channel number
#define SECRET_WRITE_APIKEY "xxxxxx"   // replace XYZ with your channel write API Key

程式碼解析：

Main.cpp

#include<ESP8266WiFi.h>
#include"DHT.h"
#include"Secrets.h"
#include"ThingSpeak.h"

#define DHTPIN D5

#define DHTTYPE DHT11   // DHT 11
//#define DHTTYPE DHT22   // DHT 22

DHT dht(DHTPIN, DHTTYPE);

char ssid[] = SECRET_SSID;
char pass[] = SECRET_PASS;
WiFiClient client;

String myStatus = "";
unsigned long myChannelNumber = SECRET_CH_ID;
const char * myWriteAPIKey = SECRET_WRITE_APIKEY;

void setup() 
{
	Serial.begin(115200);
	while (!Serial) ;

	Serial.print('\n');

	dht.begin();

	WiFi.mode(WIFI_STA); 

	// Initialize ThingSpeak
	ThingSpeak.begin(client);  
}

void loop() 
{
	// Connect or reconnect to WiFi
	if(WiFi.status() != WL_CONNECTED)
	{
		Serial.print("Attempting to connect to SSID: ");
		Serial.println(SECRET_SSID);

		int wifiTryCount = 0;
		bool wifiConnected = false;
		while(!wifiConnected)
		{
			if(wifiTryCount >= 10)
			{
				ESP.restart();
				wifiTryCount = 0;
			}
			else wifiTryCount += 1;

			// Connect to WPA/WPA2 network.
			WiFi.begin(ssid, pass);
			Serial.print(".");

			for(int x=0; 15>x; x++)
			{
				delay(1000);
				if(WiFi.status() == WL_CONNECTED) 
				{
					wifiConnected = true;
					break;
				}
			}
		} 
		Serial.println("\nConnected.");
	}

	float h = dht.readHumidity();
	float t = dht.readTemperature();

	ThingSpeak.setField(1, t);
	ThingSpeak.setField(2, h);

	// set the status
	ThingSpeak.setStatus(myStatus);

	// write to the ThingSpeak channel
	int x = ThingSpeak.writeFields(myChannelNumber, myWriteAPIKey);
	if(x == 200) Serial.println("Channel update successful.");
	else Serial.println("Problem updating channel. HTTP error code " + String(x));

	// Wait 60 seconds to update the channel again
	delay(60000);
}

程式碼解析：

Step5. 在 ThingSpeak 上察看結果

ThingSpeak 會自動將收集的點繪製成表格，我們直接打開那個網頁就可以看到最終結果了。

如果沒有看到點的話請先確認監控視窗有出現以下的畫面：

如果有出現以上畫面，那可以將滑鼠移至網頁上的圖上，如果出現 NaN 的資料，那就是溫度計的線沒有接好，將線重新壓緊然後再次等待看看是否能正常讀取到資料。

後記

小編想寫這篇也拖了好久，趕快把幾個月前學到的基礎用法拿出來筆記一下，趕快一鼓作氣解決它。

或是......拿 Arduino Uno 出來做示範？好像也不是不行，應該除了 50 行之外都不需要做修改。